Автор перевода: Майкл "Antares" Клишин	Предыдущая | Следующая | Оглавление

Selection.setFocus()

Доступность

Flash Player 5. Работа с кнопками и мувиклипами была добавлена начиная с Flash Player 6.

Синтаксис

Selection.setFocus("instanceName":String)

Параметры

instanceName Строка, определяющая путь к кнопке, мувиклипу или текстовому полю.

Возвращает

Булева величина; true если фокус установлен, false в противном случае.

Описание

Метод; передает фокус редактируемому текстовому полю, кнопке или мувиклипу, путь к которому указан в параметре instanceName. Параметр instanceName должен быть строкой, а не ссылкой. Чтобы указать путь можно использовать как точечную, так и слэш-нотацию. Можно использовать и абсолютные, и относительные пути. Если Вы используете ActionScript 2.0, должна использоваться только точечная нотация.

При передаче методу значения null в качестве параметра, удаляется текущий фокус.

Пример

В следующем примере ролик встраивается в браузер. Если пользователь не заполнил одно из текстовых полей (username_txt или же password_txt), Курсор автоматически переводится в незаполненное поле. Например, если пользователь ничего не введет в поле username_txt и кликнет по кнопке "Отправить", будет выведено сообщение об ошибке и фокус получит текстовое поле username_txt.

this.createTextField("status_txt", this.getNextHighestDepth(), 100, 70, 100, 22);
this.createTextField("username_txt", this.getNextHighestDepth(), 100, 100, 100, 22);
this.createTextField("password_txt", this.getNextHighestDepth(), 100, 130, 100, 22);
this.createEmptyMovieClip("submit_mc", this.getNextHighestDepth());
submit_mc.createTextField("submit_txt", this.getNextHighestDepth(), 100, 160, 100, 22);
submit_mc.submit_txt.autoSize = "center";
submit_mc.submit_txt.text = "Submit";
submit_mc.submit_txt.border = true;
submit_mc.onRelease = checkForm;
username_txt.border = true;
password_txt.border = true;
username_txt.type = "input";
password_txt.type = "input";
password_txt.password = true;
Selection.setFocus("username_txt");
//
function checkForm():Boolean {
  if (username_txt.text.length == 0) {
    status_txt.text = "введите имя пользователя!";
    Selection.setFocus("username_txt");
    return false;
  }
  if (password_txt.text.length == 0) {
    status_txt.text = "введите пароль!";
    Selection.setFocus("password_txt");
    return false;
  }
  status_txt.text = "успешно!!";
  Selection.setFocus(null);
  return true;
}

См. также

Selection.getFocus(), Selection.onSetFocus

Смотреть комментарии LiveDocs		Предыдущая | Следующая | Оглавление